K.Kumericki, 2011-07-12

q (OverBar[q]) →(SuperPlus[l])(SuperMinus[l]) cross section

1. Initialization (FeynCalc)

1.1 Loading packages

For Dirac traces I am using Mathematica package FeynCalc, downloadable from www.feyncalc.org

<<"HighEnergyPhysics/FeynCalc.m"

1.2 Typography

Format[p1]:=Subscript["p","1"]
Format[p2]:=Subscript["p","2"]
Format[p3]:=Subscript["p","3"]
Format[p4]:=Subscript["p","4"]
Format[Qq]:=Subscript["Q","q"]

Format[shat]:=Overscript["s", "^"]
Format[that]:=Overscript["t", "^"]
Format[uhat]:=Overscript["u", "^"]

Format[a[f_,j_]]:=Subsuperscript["a",f,j]
Format[v[f_,j_]]:=Subsuperscript["v",f,j]

Format[DiDj]:="(D^(i* ))(D^j)"

Format[ee]:="e"
Format[ML]:="(Subscript[M, L])"

1.3 Kinematics

kinrule={ScalarProduct[p1,p2]->shat/2,ScalarProduct[p3,p4]->(shat-2(ML^2))/2,ScalarProduct[p1,p3]->((ML^2)-that)/2,ScalarProduct[p2,p4]->((ML^2)-that)/2,ScalarProduct[p1,p4]->((ML^2)-uhat)/2,ScalarProduct[p2,p3]->((ML^2)-uhat)/2};

Rules to eliminate one of the three Mandelstam variables:

mandelstamu = {uhat -> 2(ML^2)-that-shat};
mandelstams = {shat -> 2(ML^2)-that-uhat};

Kinematical limits of Mandelstam (OverHat[t])

tmin=(ML^2)-(shat/2)(1+β);
tmax=(ML^2)-(shat/2)(1-β);

2. Parton cross-section

One term of  amplitude squared

ain = GS[p1].GA[μ].(v[q,i]-a[q,i] GA[5]).GS[p2].GA[ν].(v[q,j]-a[q,j] GA[5])
aout =(GS[p3]+ML).GA[ν].(v[l,j]-a[l,j] GA[5]).(GS[p4]-ML).GA[μ].(v[l,i]-a[l,i] GA[5])

ampM = Simplify[(((ee^4) DiDj)/(4 ))Contract[Tr[ain]Tr[aout]]/.kinrule/.mandelstamu]

Integrate[ampM, {that, tmin,tmax}]

Simplify[%/.(ML^2)->(shat/4)(1-(β^2))]

Cross-section

Multiplying with phase space factor and with  dΩ/ (OverHat[dt])

dsig=((β/(64 (π^2)shat))((4π)/(shat β)))%/.(ee^4)->16 (π^2)(α^2)

Drell-Yan limit (photon only, massless lepton, SM couplings)

dylimit={a[l,_]:>0,a[q,_]:>0,v[l,_]:>-1,v[q,_]:>Q,β->1,DiDj->1/(shat^2)};

dsig/.dylimit

Which is  standard expression  (cf. Halzen & Martin, Eq. 11.52).